Chap

Chap is an Easy to learn, dynamic, interpretive, isolated, and keywordless scripting language written in Rust. It is useful when you want your user to control some stuff dynamically and perform some custom calculations in a safe sandbox.

Table of content

1. Why it named 'Chap'
2. Features
3. Keywords
4. Syntax
5. Operators
6. ControlFlow
7. Samples
8. Data Types
9. Installation
10. How to use
11. TODOs for version 2.0.0
12. Builtin function

Name

Rust or راست in persian means right and Chap or چپ means left.

If you code in rust(right) too much you gradually became capitalist after a while. so you need to write some chap(left) to escape from matrix.

Features

1. Its so easy to learn, (your grandma can learn it in 15 minutes max).
2. Cross platform (chap runs on Linux, MacOS, Web(WASM) and even Windows!)
3. OOP or FP? Chap does not gives a sh*t about other programming languages and do the thing in its own way (aka Gigachap paradaim) .

Keywords

What makes a programming language hard to learn?

"Keywords"

Syntax

A normal line of code in chap has 3 chunks separated with -> operator:

chunk1 -> chunk2 -> chunk3

param1, param2 -> function_name -> $output_variable

For example:

1, 2 -> add -> $sum

1. 1 and 2 separated by "," are input params.
   
2. These input params are moving to "add" function
   
3. Finally $sum is a variable that holds the add result in it.
   

Note: "add" is not a keyword its a builtin function.

Ok but why?

English language is a "left to right" (aka LTR) language. and programming languages should follows the same rule right?

wrong:

// c base languages:
result = send(sqrt(1 + 2).toString());
   ↑       ↑    ↑     ↑       ↑
   5       4    2     1       3

// chap
1,2 -> add -> sqrt -> to_string -> send -> $result
        ↑       ↑         ↑          ↑        ↑
        1       2         3          4        5

This is acctually left to right like normal english.

TODO: "Chaining" is not supported in version 1.0.0. and every chap line can have 3 chunk max.

Syntax Rules

Make a comment with // and anything you write in right side will be ignored.

1, 2 -> add -> $sum // this is a comment

You can write many line of code in one line by using ;

1 -> $a; $a, 2-> sum -> $b; $b -> print -> $_

Input params are separated by comma character ",".

Input params can be:

1. Variable
   
2. String with " character around like: "hello world"
   
3. Int just a number: 5
   
4. Float just a normal form of floating point number 3.14
   
5. Bool is a boolean value which is a true or false
   
6. Tag starts with @. more on control flow

$a, "hello", 5, 3.14, false -> function_name -> $output_var

Function names are not case sensitive.

Function names are not sensitive about anything else:

// to_string = ToString = TOSTRING = to string = t o s t r_i_n_g

variables should starts with $ which known as most loved feature of PHP.
variable name rules:

$12 // Ok
$sp a ce // OK
$#^3 //Ok
$a,b // comma not allowed
$really? // question mark at end not allowed
$rea?lly // OK
$some->thing // -> is not allowed 

Short syntax features

If a function have no output variable you can remove chunk3:

"hello world" -> print
    ↑              ↑         ↑
   input         function   removed chunk3

If a function have no input param you can remove chunk1:

              input -> $user_input
 ↑              ↑         ↑
nothing      function    output

removing chunk2 (function name) means assign:

1 -> $variable
// its actually short form of:
1 -> assign -> $variable

If a function have no input param and output_var you just write function name:

exit

If function has output var but you removed chunk3 the result of function will get printed:

1, 2 -> add
// its short for of:
1, 2 -> add -> $temp
$temp -> print

If you just write some params. chap will print them:

1, 2
// result: 1, 2

// or
$a
// prints whatever $a is

We have worlds smallest hello world:

"Hello World"

I wish I could remove double quotes too :)

Operators

There is one operator -> which moves data from left to right and it is language logo.

Why operators are bad?
becuase they behave different with different types. look at this python example:

number = input("Enter a number:")
result = number * 5 # multiply number to 5
print(number, "* 5 =", result)

Following code has bug and result will be:

Enter a number: 3
3 * 5 = 33333
# no runtime error

Why? because python use same operator for math.multiply and strings.repeat.

So * operator is not a type safe operator and it will do unexpected things when your forget to pass right type to it and it will happen without throwing runtime errors (which is bad).

Same code in chap:

input -> $number
$number, 5 -> multiply -> $result 
$result
// error in line 2: multiply function works only with numbers int and float

Runtime errors are much better than logical error. and in chap we have repeat function:

"foo ", 3 -> repeat
// foo foo foo 

In many languges "+" operator has same problem:

# python
def add(a, b):
    a + b # concat or add? both?

add("1", "2") # 12
add(1, 2) # 3

// Chap:
"1", "2" -> concat // 12
1, 2 -> concat // 12 // you can concat integers safly
1, 2 -> add // 3
"1", "2" -> add // runtime error

debugger

You can put a ? end of line to debug that line:

1 -> $a
2 -> $b
$a, $b -> add -> $c?
// result 1, 2 -> add -> 3

Chap also has a function called "dump" which prints every variable you have.

Control Flow

You can create tag like this:

@tag_name

And you can jump to it:

@tag_name -> jump
// or
@tag_name, true -> jump_if
// or
@tag_name, 1, 1 -> jump_if_equal
// or
@tag_name, 1, 0 -> jump_if_not_equal

loop

jumping backward makes loops

@l
    "Hello util your battery dies"
@l -> jump

if

@i, 1, 1 -> jump_if_equal
    "this will not print"
@i

Note: Indenation is not nessessery

Samples

hello_world.chp

"Hello world"

Hello world

couter.chp

0 -> $counter
@l
    $counter -> increase
@l, $counter, 100 -> jump_if_not_equal
$counter

100

number_guess_game.chp

1,10 -> random_number -> $answer
@loop
    input -> $guess
    $guess -> to_int -> $guess
    @win, $answer, $guess -> jump_if_equal
    "wrong"
@loop -> jump

@win
"you win"

1
wrong
2
wrong
3
you win

christmas_tree.chp

0 -> $counter
@loop
    $counter -> increase

    "*", $counter -> repeat -> $stars
    10, $counter -> minus -> $space_size
    " ", $space_size -> repeat -> $spaces

    $spaces, $stars -> cat
@loop, $counter, 10 -> jump if not equal

         *
        **
       ***
      ****
     *****
    ******
   *******
  ********
 *********
**********

DataTypes

// REPL log
-> 1 -> type_of
int
-> 3.14 -> type of
float
-> "ali" -> TypeOf
string
-> true -> type      
boolean

// TODO arrays

Installation

Download release

link

Build

git clone https://github.com/ali77gh/Chap
cargo build --release
sudo cp ./target/release/chap /usr/bin

How To Use

REPL

./repl/mod.rs

❯ chap
-> "hello world"
hello world
-> 

File_executor

./file_executor/mod.rs

❯ chap number_guess_game.chp 
1
wrong
2
wrong
3
you win answer was: 3

Library

./lib.rs

As lib

cargo build --release --lib

As Wasm module

TODO

TODOs

Version 2.0.0:

• Arrays
• Chaining syntax (1,2->add->toString->print)
• tests for builtin functions
• static analyzer
• fix: 'random' module will not work on WASM
• eval function
• function name autocompelete (maybe a simple LSP)
• WASM lib
• ChapApp

Builtin Functions

runtime/builtin_function
Chap has 46 builtin function(version 1.0.1) (less than javas keywords)